defmodule Fussy.Validators.Integer do
  @behaviour Fussy.Validator

  defstruct strict: true,
            gt: nil,
            lt: nil,
            gte: nil,
            lte: nil,
            multiple_of: nil

  @opaque t :: %__MODULE__{}

  @spec new(
          strict: boolean(),
          gt: number() | nil,
          lt: number() | nil,
          gte: number() | nil,
          lte: number() | nil,
          multiple_of: integer() | nil
        ) :: __MODULE__.t()
  def new(args \\ []), do: struct!(%__MODULE__{}, args)

  @impl true
  def validate(%__MODULE__{strict: false} = v, n) when is_float(n) do
    validate(v, trunc(n))
  end

  @impl true
  def validate(%__MODULE__{gt: gt, lt: lt, gte: gte, lte: lte, multiple_of: multiple_of}, n)
      when is_integer(n) do
    [gt: gt, lt: lt, gte: gte, lte: lte, multiple_of: multiple_of]
    |> Enum.filter(fn
      {_, nil} -> false
      _ -> true
    end)
    |> Enum.reduce([], fn validator, errors ->
      case validate_with(validator, n) do
        :ok -> errors
        reason -> [reason | errors]
      end
    end)
    |> then(fn
      [] -> {:ok, n}
      errors -> {:error, errors |> Enum.reverse()}
    end)
  end

  @impl true
  def validate(%__MODULE__{strict: false} = v, bin) when is_binary(bin) do
    case Integer.parse(bin) do
      {n, ""} ->
        validate(v, n)

      {_, _} ->
        {:error, ["must be an integer"]}

      :error ->
        {:error, ["must be an integer"]}
    end
  end

  @impl true
  def validate(_, _), do: {:error, ["must be an integer"]}

  defp validate_with({:gt, gt}, n) when n > gt, do: :ok
  defp validate_with({:gt, gt}, _), do: "must be greater than #{gt}"

  defp validate_with({:gte, gte}, n) when n >= gte, do: :ok
  defp validate_with({:gte, gte}, _), do: "must be greater than or equal to #{gte}"

  defp validate_with({:lt, lt}, n) when n < lt, do: :ok
  defp validate_with({:lt, lt}, _), do: "must be less than #{lt}"

  defp validate_with({:lte, lte}, n) when n <= lte, do: :ok
  defp validate_with({:lte, lte}, _), do: "must be less than or equal to #{lte}"

  defp validate_with({:multiple_of, multiple_of}, n) do
    if Integer.mod(n, multiple_of) == 0 do
      :ok
    else
      "must be a multiple of #{multiple_of}"
    end
  end
end