defmodule Mix.Tasks.Lightpanda.Install do
  @moduledoc """
  Installs Lightpanda under `_build`.

  ```bash
  $ mix lightpanda.install
  $ mix lightpanda.install --if-missing
  ```

  By default, it installs #{LightpandaEx.latest_version()} but you
  can configure it in your config files, such as:

      config :lightpanda_ex, version: "#{LightpandaEx.latest_version()}"

  The binary is downloaded from GitHub releases by default. Configure
  `:release` to `"nightly"` to track nightly builds, or configure `:url`
  with a custom `$version`/`$target` URL template to use a mirror.

  ## Options

      * `--runtime-config` - load the runtime configuration
        before executing command

      * `--if-missing` - install only if the given version
        does not exist
  """

  @shortdoc "Installs Lightpanda under _build"
  @compile {:no_warn_undefined, Mix}

  use Mix.Task

  @impl true
  def run(args) do
    valid_options = [runtime_config: :boolean, if_missing: :boolean]

    case OptionParser.parse_head!(args, strict: valid_options) do
      {opts, []} ->
        if opts[:runtime_config] do
          Mix.Task.run("app.config")
        else
          Mix.Task.run("loadpaths")
        end

        if opts[:if_missing] && latest_version?() do
          :ok
        else
          if function_exported?(Mix, :ensure_application!, 1) do
            Mix.ensure_application!(:inets)
            Mix.ensure_application!(:ssl)
          end

          LightpandaEx.install()
        end

      {_, _} ->
        Mix.raise("""
        Invalid arguments to lightpanda.install, expected one of:

            mix lightpanda.install
            mix lightpanda.install --runtime-config
            mix lightpanda.install --if-missing
        """)
    end
  end

  defp latest_version?() do
    version = LightpandaEx.configured_version()
    match?({:ok, ^version}, LightpandaEx.bin_version())
  end
end